home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 014 / markatrb.arc / MARK.ASM next >
Assembly Source File  |  1985-11-16  |  7KB  |  263 lines
  1.     name    mark
  2.     page    55,132
  3.     title    'MARK --- set attribute of file'
  4. ;
  5. ; MARK --- Utility to set attribute of file.
  6. ;
  7. ; Requires PC-DOS 2.0 or higher for execution.
  8. ;
  9. ; Program is called by command of the form: 
  10. ;
  11. ;     A>MARK path\file.ext /x
  12. ;
  13. ; where x=A for Archive, H for hidden, R for read-only,
  14. ; or N for normal (all attrib bits off).  
  15. ; 
  16. ;
  17. ; Copyright (c) 1985 Charles C. Caro
  18. ;
  19. ; May be freely modified and reproduced
  20. ; for non-commercial use.
  21. ;
  22.  
  23. cr    equ    0dh        ;ASCII carriage return
  24. lf    equ    0ah        ;ASCII line feed
  25. eom    equ    '$'        ;end of message flag 
  26.  
  27. command    equ    80h        ;Command line buffer
  28.  
  29. rd_only    equ     01h        ;file attributes
  30. hidden    equ    02h        
  31. system    equ    04h
  32. volume    equ    08h
  33. subdir    equ    10h
  34. archive    equ    20h
  35.  
  36.  
  37. cseg    segment    para public 'CODE'
  38.  
  39.     assume    cs:cseg,ds:data,es:data,ss:stack
  40.  
  41. mark    proc    far        ;entry point from PC-DOS
  42.  
  43.     push    ds        ;save DS:0000 for final
  44.     xor    ax,ax        ;return to PC-DOS
  45.     push    ax
  46.     mov    ax,data        ;make our data segment addressable
  47.     mov    es,ax        ;via the ES register
  48.     call    infile        ;get path and name for
  49.                 ;file to be modified. 
  50.     jnc    mark1        ;jump if filename was ok
  51.     mov    dx,offset msg1    ;filename absent or illegal,
  52.     call    error        ;print error message and exit
  53.     ret
  54.  
  55. mark1:                ;filename was ok, now try
  56.     call    get_switch    ;and find the switch
  57.     jnc    mark2        ;jump if switch was ok
  58.     mov    dx,offset msg7    ;missing switch, print error
  59.     call    error        ;message and exit
  60.     ret            
  61.  
  62. mark2:                ;found legal switch, now 
  63.     push    dx        ;save addr of success message
  64.     mov    ax,es        ;make our data segment addressable
  65.     mov    ds,ax        ;via the DS register
  66.                 ;CX=attrib bits, 
  67.                 ; already set by "get_switch"
  68.                 ;DS:DX=addr of filename
  69.     mov    dx,offset input_name
  70.     mov    ah,43h        ;function 43h=CHMOD
  71.     mov     al,01        ;AL=01 for set attrib
  72.     int    21h        ;make request to PC-DOS
  73.     jnc    mark3        ;if CY=0 jump, successful call
  74.                 ;if CY=1 call failed,     
  75.     pop    dx        ;clean up stack, and
  76.     mov    dx,offset msg2    ;print error message
  77.     call    error
  78.     ret
  79.  
  80. mark3:                ;attribute was modified,
  81.     mov    dx,offset msg3    ;print 1st part of success message
  82.     mov    ah,9
  83.     int    21h
  84.                 ;print filename
  85.     mov    dx,offset input_name
  86.     call    pasciiz 
  87.     pop    dx        ;print last part of success msg.
  88.           mov    ah,9        
  89.     int    21h        
  90.     
  91.     ret            ;final exit to PC-DOS
  92. mark    endp
  93.  
  94. pasciiz    proc    near        ;print the ASCIIZ string
  95.                 ;whose offset is in DX on
  96.                 ;the standard output device.
  97.                 ;Regs AX, BX also destroyed.
  98.     mov    bx,dx        ;let BX=offset of string
  99. pasciiz1:
  100.     mov    dl,[bx]        ;get next char from string
  101.     or    dl,dl        ;if char.=zero,end of string
  102.     jz    pasciiz9    ;jump if end
  103.     cmp    dl,'A'        ;if it is an upper-case alpha
  104.     jb    pasciiz2    ;character,fold to lower case
  105.     cmp    dl,'Z'        ;Note: Inclusive Or of an alpha
  106.     ja    pasciiz2    ;ASCII character with 20h has the
  107.     or    dl,20h        ;effect of folding to lower case.
  108. pasciiz2:
  109.     mov    ah,2        ;function 2=output char.
  110.     int    21h        ;request output by PC-DOS
  111.     inc    bx        ;advance to next string position
  112.     jmp    short pasciiz1
  113. pasciiz9:            ;done with string output,
  114.     ret            ;return to caller
  115. pasciiz endp
  116.  
  117. infile    proc    near        ;Capture the name of a file
  118.                 ;from the command tail buffer
  119.                 ;where it was left by PC-DOS,
  120.                 ;transferring it into a local
  121.                 ;buffer in the form of an
  122.                 ;ASCIIZ string.
  123.  
  124.                 ;DS:SI <-  addr of command tail
  125.     mov    si,offset command
  126.                 ;ES:DI <-  addr of local buffer
  127.     mov    di,offset input_name
  128.     cld            ;make sure direction flag cleared
  129.     lodsb            ;first check count byte to make
  130.     or    al,al        ;sure command tail is present
  131.     jz    infile4        ;return error status if not.
  132. infile1:            ;scan over leading blanks to
  133.     lodsb            ;find the path and filename
  134.     cmp    al,cr        ;if we run into carriage return,
  135.     jz    infile4        ;filename is missing so exit.
  136.     cmp    al,20h        ;if this char is a blank,
  137.     jz    infile1        ;keep scanning.
  138. infile2:            ;found 1st char of name, 
  139.     stosb            ;transfer the name to local buffer.
  140.     lodsb            ;check next character, found
  141.     cmp    al,cr        ;end of string yet?
  142.     je    infile3        ;yes if either carriage return
  143.     cmp    al,20h     
  144.     jne    infile2
  145. infile3:            ;path and filename successfully 
  146.     xor    al,al        ;transferred to local buffer,
  147.     stosb            ;store 0 byte at end of string
  148.     clc            ;and exit with Carry flag =0
  149.     ret
  150. infile4:            ;some type of error was detected
  151.     stc            ;so exit with Carry flag =1
  152.     ret
  153. infile    endp
  154.  
  155.  
  156. get_switch proc    near        ;Scan the input line for a "/"
  157.                 ;delimiting a switch, then make
  158.                 ;sure it is legal.  
  159.                 ;Return CY=0 if legal switch, and
  160.                 ;CX=attrib byte, DX=msg addr
  161.                 ;Return CY=1 if switch no good 
  162.     mov    si,offset command+1  ; DS:SI = addr of command line
  163. get_switch1:            ;look for "/" character
  164.     lodsb
  165.     cmp    al,cr        ;if we run into a carriage return,
  166.     jz    get_switch9     ;switch missing so take error exit.
  167.     cmp    al,'/'    
  168.     jne    get_switch1    ;not '/' yet, keep looking.
  169.     lodsb            ;found '/', pick up next char.
  170.     or    al,20h        ;and fold to lower case.
  171.     cmp    al,'r'        ;R = read only
  172.     jne    get_switch2     ;not R, jump
  173.     mov    cx,rd_only    ;R so set read only attrib bit
  174.     mov    dx,offset msg5
  175.     ret            ;return CY=0 for success
  176. get_switch2:            ;check for H=hidden
  177.     cmp    al,'h'
  178.     jne    get_switch3    ;not H, jump
  179.     mov    cx,hidden    ;H so set hidden attrib bit
  180.     mov    dx,offset msg4
  181.     ret            ;return CY=0 for success
  182. get_switch3:            ;check for N=normal
  183.     cmp    al,'n'
  184.     jne    get_switch4    ;not N,jump
  185.     mov    cx,0        ;clear all attrib bits
  186.     mov    dx,offset msg6
  187.     ret            ;return CY=0 for success
  188. get_switch4:            ;check for A=Archive
  189.     cmp    al,'a'
  190.     jne    get_switch9    ;not A,jump to error exit
  191.     mov    cx,archive    ;A so set archive attrib bit
  192.     mov    dx,offset msg8
  193.     ret            ;return CY=0 for success
  194. get_switch9:            ;missing or illegal switch,
  195.     stc            ;return CY flag=1 as alarm
  196.     ret
  197. get_switch endp
  198.  
  199.  
  200. error    proc    near        ;print error message
  201.     mov    ax,data        ;make sure data area addressable
  202.     mov    ds,ax
  203.     mov    ah,9        ;print error type
  204.     int    21h
  205.     mov    dx,offset helpmsg
  206.     mov    ah,9        ;also print HELP information
  207.     int    21h
  208.     ret            ;back to caller
  209. error    endp
  210.  
  211.  
  212. cseg    ends
  213.  
  214.  
  215.                 ;declare a data segment for
  216.                 ;storage of miscellaneous
  217.                 ;constants and variables
  218. data    segment    para public 'DATA'
  219.  
  220. input_name db    64 dup (0)    ;buffer for path and file name
  221.  
  222. msg1    db    cr,lf
  223.     db    'Missing file name.',eom
  224.  
  225. msg2    db    cr,lf
  226.     db    'File not found.',eom
  227.  
  228. msg3    db    cr,lf
  229.     db    'Attribute of file ',eom
  230.  
  231. msg4    db    ' has been set to Hidden.'
  232.     db    cr,lf,eom
  233.  
  234. msg5    db    ' has been set to Read-Only.'
  235.     db    cr,lf,eom
  236.  
  237. msg6    db    ' has been set to Normal.'
  238.     db    cr,lf,eom
  239.  
  240. msg7    db    cr,lf
  241.     db    'Missing or illegal switch.',eom
  242.  
  243. msg8    db    ' has been set to Archive.'
  244.     db    cr,lf,eom
  245.  
  246. helpmsg    db    '  Command should be in the form: '
  247.     db    cr,lf,lf
  248.     db    '  MARK filename /x'
  249.     db    cr,lf,lf
  250.     db    'x=A for archive, H for hidden, N for normal, R for read-only.'
  251.     db    cr,lf,eom
  252.  
  253. data    ends
  254.  
  255.                 ;declare a stack segment of 64 bytes
  256.                 ;for use as scratch area by such
  257.                 ;instructions as PUSH, POP, CALL, RET 
  258. stack    segment    para stack 'STACK'
  259.     db    64 dup (?) 
  260. stack    ends
  261.  
  262.     end    mark
  263.